[MLKPAI-F01-EG4D]FPGA程序设计基础实验连载-06 PWM呼吸灯实验 - FPGA+AI数字世界

呼吸灯采用 PWM 的方式，在固定的频率下，通过调整占空比的方式来控制 LED 灯亮度的变化。一般人眼睛对于80Hz以上刷新频率则完全没有闪烁感。频率太小的话，LED灯看起来就会闪烁，当频率大于50Hz的时候，人眼就会产生视觉暂留效果，基本就看不到闪烁了，就是一个常亮的LED灯。如果高电平点亮LED灯，低电平熄灭LED灯，占空比为100%，LED 灯最亮，占空比为0%，LED 灯最暗。所以，在频率一定下，可以用不同占空比改变LED灯的亮度。

呼吸灯是由两个部分组成，一个是由亮到暗的过程，一个是由暗到亮的过程，再由简介可知我们是在固定的频率下通过调整高电平的占空比来调控 LED 灯的亮度。第一个过程由亮到暗的过程为t=2s，如果高电平点亮LED灯，低电平熄灭LED灯，不同的占空比显示不同的亮度，占空比就要在2s之间逐渐由100%减小至0%，如果我们把2s划分成100份，那么每一个占空比就要保持t1=2s/100=20ms。由于占空比100%减小到0%一共变化了100次，占空比=高电平周期/整个周期t1，所以需要将一个占空比周期t1划分成100份，从而达到高电平周期每减小一个周期t2，占空比就减少1%，t2=20ms/100=200us。

module pwm_light#
(
parameter REF_CLK = 32'd25000000
)
(
input I_sysclk,
input I_rstn,
output O_pwm
);
localparam T20US_SET = REF_CLK/5000 - 1; //set 200us,可根据实际晶振频率进行修改
localparam T20MS_SET = 100 - 1; //set 20ms
localparam PWM_SET = 100 - 1; //Set PWM duty cycle adjustment times
reg [23:0] t20us_cnt;
reg [9 :0] t20ms_cnt;
reg [9 :0] pwm_cnt;
reg PWM_S;
//记录计数状态
wire t20us_done;
wire t20ms_done;
//是否计满200us
assign t20us_done = (t20us_cnt == T20US_SET);
//是否计满20ms
assign t20ms_done = t20us_done & (t20ms_cnt == T20MS_SET) ;
//1us base timer
always @(posedge I_sysclk or negedge I_rstn)begin //系统时钟的上升沿以及复位的下降沿触发
if(I_rstn == 1'b0) //复位清零
t20us_cnt <= 0;
else if(t20us_cnt < T20US_SET) //t20us_cnt目标值T20US_SET
t20us_cnt <= t20us_cnt + 1'b1; //本轮计数未完成则+1
else
t20us_cnt <= 24'd0; //若达目标值则清零,进行新一轮计数
end
//1ms pwm compare timer,based on 1us base timer
always @(posedge I_sysclk or negedge I_rstn)begin
if(I_rstn == 1'b0)
t20ms_cnt <= 0;
else if(t20us_done) //前一级(200us)的一轮计数完成则+1
t20ms_cnt <= (t20ms_cnt < T20MS_SET) ? (t20ms_cnt + 1'b1) : 10'd0;
else //否则保持
t20ms_cnt <= t20ms_cnt;
end
//PWM counter for generating duty cycle parameters as well as PWM adjustment count
always @(posedge I_sysclk or negedge I_rstn)begin
if(I_rstn == 1'b0)
pwm_cnt <= 0;
else if(t20ms_done)
pwm_cnt <= (pwm_cnt < PWM_SET) ? (pwm_cnt + 1'b1) : 10'd0; //前一级(20ms)的一轮计数完成则+1
else
pwm_cnt <= pwm_cnt; //否则保持
end
//switch breathing state
always @(posedge I_sysclk or negedge I_rstn)begin
if(I_rstn == 1'b0)
PWM_S <= 0;
else if(t20ms_done && (pwm_cnt == PWM_SET)) //pwm_cnt == PWM_SET时(即计满2s),PWM_S状态进行翻转
PWM_S <= ~PWM_S;
else
PWM_S <= PWM_S;
end
//PWM wave generating
assign O_pwm = PWM_S ? (pwm_cnt >= t20ms_cnt) : (pwm_cnt < t20ms_cnt);
//在一轮计数中,t20ms_cnt逐渐增大
//若PWM_S==1,O_pwm输出为1的频率越来越小,表现为LED灯逐渐变暗
//若PWM_S==0,O_pwm输出为1的频率越来越大,表现为LED灯逐渐变亮
endmodule

复制代码